#include "colors.inc"    // The include files contain
#include "shapes.inc"    // pre-defined scene elements
#include "finish.inc"
#include "metals.inc"
#include "stones.inc"

#version 3.6;

/*
 * Alcoves leading to the chess board in the Ghost Tower of Inverness.
 *
 * Last modified 10/22/2005 by Denton Gentry.
 */

global_settings {
	assumed_gamma 1.8
	ambient_light rgb<1, 1, 1>
}

// Texture by Chuck Fusner, http://www.enter.net/~cfusner
#declare RoughStone = texture { //rough stone texture...
	pigment { //nice and random on the pigment.
		granite
		color_map {
		[ 0 rgb .5 ]
		[ .25 rgb .65 ]
		[ .5 rgb .5 ]
		[ .75 rgb .7 ]
		[ 1 rgb .5 ]
		}
		frequency 100
	}
	normal { /*love that crackle! It's apparently quite
                 computation intensive, but with just the
                 right turbulence, it's got a range of apps.*/
		crackle 1
		warp {
		turbulence <.4,.4,.4> /*no more than this for a rough
                                    stone effect. And less will
                                    look more "crystaline"*/
		lambda 2 //these you can tinker with
		octaves 6 //for a variety of effects
		omega .5 //though here they are at defaults.
		}
	}
	finish {
		specular .1 roughness 1
		diffuse .55
	}
}

#local Mortar = texture {
	pigment { Gray80 }
}

#local SmoothStone = texture {
	pigment { Gray90 }
	normal {
		crackle 1
	}
	finish {
		specular .01 roughness 1
		diffuse .01
	}
}

#local T_farwall = texture {
	brick
	texture { Mortar }
	texture { RoughStone }
	brick_size 1
	mortar 0.05
	scale <1,0.5,1>
	translate <0,0.25,0>
}

#local T_wall = texture {
	brick
	texture { Mortar }
	texture { SmoothStone }
	brick_size 1
	mortar 0.05
	scale <1,0.5,1>
}

#declare T_alcove = T_Grnt9

#declare T_floor = texture {
	brick
	texture { Mortar }
	texture { SmoothStone }
	brick_size 1
	mortar 0.03
}

#declare alcove = blob {
			sphere {<0,1.65,0>, 0.25, strength 1.01 }
			sphere {<0,1.1,0>,  1.00, strength 1.001  scale <1,1,1> }
			sphere {<0,0.0,0>,  1.08, strength 1.3 	  scale <1,1.95,1> }
			scale <0.93,1,1>
			texture { T_alcove }
		}

object {
	difference {
		box  { <-20, 0, 0>, <20, 20, 20> }
		object {
			alcove
			translate <0,0,0>
		}
		object {
			alcove
			translate <-2,0,0>
		}
		object {
			alcove
			translate <-1,0,0>
		}
		object {
			alcove
			translate <1,0,0>
		}
		object {
			alcove
			translate <2,0,0>
		}

//		blob {
//			sphere {<-2,1.65,0>, 0.2, strength 1.01 }
//			sphere {<-2,1.1,0>, 0.45, strength 1.01 }
//			cylinder { <-2,0,0>, <-2,1.2,0>, 1.9, strength 1.1 }
//			texture { T_alcove }
//		}
	}
	texture { T_farwall }
}
object {
	plane { <-1,0,0>, 2.7 }
	texture { T_wall }
}
object {
	plane { < 1,0,0>, 2.7 }
	texture { T_wall }
}
object {
	plane { <0,-1,0>, -2.7 }
	texture { T_floor }
}

object {
	plane { <0,1,0>, 0 }
	texture { T_floor }
}

light_source { <  0, 1, -10> color Gray20 shadowless }
light_source { < 10, 1, -10> color Gray20 shadowless }
light_source { <-10, 1, -10> color Gray20 shadowless }
light_source { <  0, 1, -10> color Gray20 shadowless }
light_source { <  0, 1, -10> color Gray20 shadowless }

camera {
	location <0, 1.3, -5>
	look_at  <0, 1.3, 0>
}

background { color Black }