#version 3.1;

/*
 * The Apparatus the Unlife was using to subvert the great EarthNode
 * at the Heart of the World. Roughly 13 feet tall and 6 feet wide
 * at the base.
 *
 * Scale is 1 POVunit == 1 foot.
 *
 * created 4/26/99 Denton Gentry. Free for derivative use.
 */

#include "colors.inc"
#include "metals.inc"

camera {
	location <65,14,45>
	look_at <0,10,0>
}


light_source { <65, 25, 40> color Gray30 }
light_source { <0, 16, 0> color White }


global_settings {
	assumed_gamma 1.8
	ambient_light rgb<1, 1, 1>
}

#local T_unlife_forcefield = texture {
	pigment { color rgbf <0.87, 0.58, 0.98, 0.9> }
	finish {
		ambient 0.5
		diffuse 0.1
		brilliance 1.0
		reflection 0.001
		irid {
			0.30
			thickness 0.4
			turbulence 0.6
		}
	}
}
#local I_unlife_forcefield = interior {
	caustics 0.2
}

#local T_Unlife_Beam = texture {
	pigment {
		marble
		color_map {
			[ 0.00 0.45 color rgbt<0,0,0,1> color rgbt<0,0,0,1> ]
			[ 0.45 0.60 color rgbt <0.5,0,0,0.5> color rgbt<0.9,0,0.1,0.9> ]
			[ 0.60 0.75 color rgbt<0.9,0,0.1,0.9> color rgbt <0.5,0,0,0.5> ]
			[ 0.75 1.00 color rgbt<0,0,0,1> color rgbt<0,0,0,1> ]
		}
	}
	finish {
		ambient 0.7
		diffuse 0.2
		brilliance 2.0
	}
}

#local Apparatus = merge {
	// the metal structure
	merge {
		cylinder { <4, 0.2, 0>, <2, 13, 0>, 0.2 }
		cylinder { <-4, 0.2, 0>, <-2, 13, 0>, 0.2 }
		cylinder { <0, 0.2, 4>, <0, 13, 2>, 0.2 }
		cylinder { <0, 0.2, -4>, <0, 13, -2>, 0.2 }

		cylinder { <2, 13, 0>, <0, 13, 2>, 0.15 }
		cylinder { <0, 13, 2>, <-2, 13, 0>, 0.15 }
		cylinder { <-2, 13, 0>, <0, 13, -2>, 0.15 }
		cylinder { <0, 13, -2>, <2, 13, 0>, 0.15 }

		cylinder { <4, 2, 0>, <0, 2, 4>, 0.15 }
		sphere { <4, 2, 0>, 0.15 }
		cylinder { <0, 2, 4>, <-4, 2, 0>, 0.15 }
		sphere { <0, 2, 4>, 0.15 }
		cylinder { <-4, 2, 0>, <0, 2, -4>, 0.15 }
		sphere { <-4, 2, 0>, 0.15 }
		cylinder { <0, 2, -4>, <4, 2, 0>, 0.15 }
		sphere { <0, 2, -4>, 0.15 }

		// cross-braces
		cylinder { <4, 2, 0>, <0, 13,  2>, 0.15 }
		cylinder { <-4, 2, 0>, <0, 13, -2>, 0.15 }
		cylinder { <0, 2, 4>, <2, 13, 0>, 0.15 }
		cylinder { <0, 2, -4>, <-2, 13, 0>, 0.15 }
		cylinder { <4, 2, 0>, <0, 13, -2>, 0.15 }
		cylinder { <-4, 2, 0>, <0, 13, 2>, 0.15 }
		cylinder { <0, 2, 4>, <-2, 13, 0>, 0.15 }
		cylinder { <0, 2, -4>, <2, 13, 0>, 0.15 }

#local LensR = 25;

		// lens mounting bracket
		torus { 1.9, 0.1
			rotate z*90
			rotate z*LensR
			translate y*15
		}
		sphere { <0, 15, -2>, 0.15 }
		sphere { <0, 15,  2>, 0.15 }
		cylinder { <0, 13, -2>, <0, 14, -2>, 0.15 }
		cylinder { <0, 13,  2>, <0, 14,  2>, 0.15 }

		texture { T_Chrome_2A }
	}


	// the lens
	intersection {
		sphere { < 9.8, 0, 0>, 10 }
		sphere { <-9.8, 0, 0>, 10 }

		rotate z*LensR
		translate y*15

		texture {
			pigment { color rgb <0.1, 0.1, 0.1> }
			finish  {
				ambient 0.1 diffuse 0.1
				reflection 0.1
				specular 0.8 roughness 0.003
			}
		}
	}

	// the beam
	cone {
		<0,0,0>, 0.5
		<-10.5,0,0>, 3
		open

		texture { T_Unlife_Beam scale 2.0 }

		rotate z*LensR
		translate y*15

		no_shadow
	}
}

#local T_EarthNode = texture {
	pigment { color rgb <1.0, 1.0, 0.8> }
	finish {
		ambient 0.8
		diffuse 0.8
		brilliance 20.0
	}
}

#local EarthNode = intersection {
	sphere { <0, -13, 0>, 25 }
	plane { <0, -1, 0>, 0 }
	scale <1, 1.1, 1>

	texture { T_EarthNode }

	hollow
	no_shadow
}

#local BeamField = sphere { <0, -13, 0>, 27
	scale <1, 1.1, 1>

	texture { T_Unlife_Beam rotate z*45 rotate y*4 }

	hollow
	no_shadow
}


#local ForceField = intersection {
	sphere { <0, -25, 0>, 58 }
	plane { <0, -1, 0>, 0 }
	scale <1, 1.3, 1>

	texture { T_unlife_forcefield }
	interior { I_unlife_forcefield }
}

#local BlackRobe = merge {
	// torso
	cone { <0,0,0>, 1
		<0,4,0>, 0.4
	}
	cone { <0,0,0>, 0.22 <2,0,0>, 0.33
		rotate z*-10
		translate y*4
	}
	cone { <0,0,0>, 0.22 <-2,0,0>, 0.33
		rotate z*10
		translate y*4
	}
	cylinder { <0,4,0>, <0,4.5,0>, 0.36 }
	sphere { <0,4.5,0>, 0.4 }

	texture {
		pigment { Black }
		finish { ambient 0.1 diffuse 0.1 }
	}
}

object { Apparatus translate x*35 }
object { EarthNode }
object { BeamField }
object { ForceField }

// The black-robed sorcerors
object { BlackRobe translate z*33 rotate y*20 }
object { BlackRobe translate z*33 rotate y*60 }
object { BlackRobe translate z*33 rotate y*120 }
object { BlackRobe translate z*33 rotate y*170 }
object { BlackRobe translate z*33 rotate y*220 }
object { BlackRobe translate z*33 rotate y*280 }
object { BlackRobe translate z*33 rotate y*320 }


#local T_Ground = texture { pigment { DarkBrown } }

plane { <0, -1, 0>, 0.00001
	texture { T_Ground }
}

// a Starry night sky
#local T_Starfield = texture {
	pigment {
		granite
		color_map {
			[ 0.000  0.800 color rgbft<0,0,0,1,1> color rgbft<0,0,0,1,1> ]
			[ 0.800  0.806 color Gray20 color Gray40 ]
			[ 0.806  0.812 color Gray40 color Gray60 ]
			[ 0.812  0.818 color Gray60 color Gray80 ]
			[ 0.818  0.824 color Gray80 color Gray95 ]
			[ 0.824  0.832 color Gray95 color White  ]
			[ 0.832  1.000 color rgbft<0,0,0,1,1> color rgbft<0,0,0,1,1> ]
		}
	scale .02
	}
	finish { ambient 1 }
}

sphere { <0,0,0>,300
	texture{ T_Starfield scale 150 rotate x*90 }
	no_shadow
	hollow
}

sky_sphere {
	pigment { Black }
}