#declare Temp_Vers = version;
#version 3.1;

#declare TestRender = 1;

/*
 */

#if (TestRender)
#include "colors.inc"
#include "metals.inc"

camera {
	angle 20
	location<-2,2,-10>
	look_at<0,-0.2,0>
}

light_source { <10, 20, -10> color White }

global_settings {
	assumed_gamma 1.8
	ambient_light rgb<1, 1, 1>
}

background { Gray90 }
#end

#local T_Cestus_leather = texture {
	pigment { Tan }
	finish {
		specular 0.1
		roughness 0.02
	}
}

#declare Cestus = merge {
	intersection {
		blob {
			threshold .65

			cylinder { <-.01,-1.13,0>, <-.01,-1.18,0>,.43 1 scale <1.4, 1.2, 0.95> }
			sphere   { <-.01,-1.13,0>, -0.2, 1 scale <1.4, 1.2, 0.95> }
			cylinder { <-.16,-1.13,0>, <-.16,-1.18,0>,.43 1 scale <1.4, 1.2, 0.95> }
			sphere   { <-.16,-1.13,-.05>, -0.3, 1 scale <1.4, 1.2, 0.95> }

			sphere   { <-.23,-.32,0>,.43, 1 scale <1.95,1.05,.8> }   //palm
			sphere   { <+.12,-.41,0>,.43, 1 scale <1.95,1.075,.8> }  //palm
			sphere   { <-.23,-.63,0>, .45, .75 scale <1.78, 1.3,1> } //midhand
			sphere   { <+.19,-.63,0>, .45, .75 scale <1.78, 1.3,1> } //midhand
			sphere   { <-.22,-.73,0>, .45, .85 scale <1.4, 1.25,1> } //heel
			sphere   { <+.19,-.73,0>, .45, .85 scale <1.4, 1.25,1> } //heel

			cylinder { <-.65,-.28,0>, <-.65,.28,-.05>, .26, 1 }    //lower pinky
			cylinder { <-.65,.28,-.05>, <-.65, .68,-.2>, .26, 1 }  //upper pinky

			cylinder { <-.3,-.28,0>, <-.3,.44,-.05>, .26, 1 }      //lower ring
			cylinder { <-.3,.44,-.05>, <-.3, .9,-.2>, .26, 1 }     //upper ring

			cylinder { <.05,-.28,0>, <.05, .49,-.05>, .26, 1 }     //lower middle
			cylinder { <.05,.49,-.05>, <.05, .95,-.2>, .26, 1 }    //upper middle

			cylinder { <.4,-.4,0>, <.4, .512, -.05>, .26, 1 }      //lower index
			cylinder { <.4,.512,-.05>, <.4, .85, -.2>, .26, 1 }    //upper index

			cylinder { <.41, -.95,0>, <.85, -.68, -.05>, .25, 1 }  //lower thumb
			cylinder { <.85,-.68,-.05>, <1.2, -.4, -.2>, .25, 1 }  //upper thumb

			sphere { <-.65,.28,-.05>, .26, -1 } //counteract pinky knuckle bulge
			sphere { <-.65,-.28,0>, .26, -1 }   //counteract pinky palm bulge

			sphere { <-.3,.44,-.05>, .26, -1 }  //counteract ring knuckle bulge
			sphere { <-.3,-.28,0>, .26, -1 }    //counteract ring palm bulge

			sphere { <.05,.49,-.05>, .26, -1 }  //counteract middle knuckle bulge
			sphere { <.05,-.28,0>, .26, -1 }    //counteract middle palm bulge

			sphere { <.4,.512,-.05>, .26, -1 }  //counteract index knuckle bulge
			sphere { <.4,-.4,0>, .26, -1 }      //counteract index palm bulge

			sphere { <.85,-.68,-.05>, .25, -1 } //counteract thumb knuckle bulge
			sphere { <.41,-.7,0>, .25, -.89 }   //counteract thumb heel bulge
  
			texture { T_Cestus_leather }
		}
		box { <-10, -1.35, -10>, <10, 10, 10> }
	}
	// control box
	merge {
		box { <-0.3, -1, 0>, <0.12, -0.8, 0.28> texture { T_Chrome_2A } }

		box { <-0.26, -0.97, 0.27>, <-0.22, -0.83, 0.2801> pigment { Black } }
		box { <-0.20, -0.97, 0.27>, <-0.16, -0.83, 0.2801> pigment { Red } }
		box { <-0.14, -0.97, 0.27>, <-0.10, -0.83, 0.2801> pigment { Red } }
		box { <-0.08, -0.97, 0.27>, <-0.04, -0.83, 0.2801> pigment { Red } }
		box { <-0.02, -0.97, 0.27>, < 0.02, -0.83, 0.2801> pigment { Red } }
		box { < 0.04, -0.97, 0.27>, < 0.08, -0.83, 0.2801> pigment { Red } }

	}
}


#if (TestRender)
object { Cestus
	rotate y*170
}
#end

#version Temp_Vers;