#include "colors.inc"
#include "finish.inc"
#include "stones.inc"

#version 3.1;

/*
 * A wall constructed of rough stone blocks. Intended for use as a texture
 * map for dungeon scenes.
 *
 * Last modified 11/21/99 by Denton Gentry.
 *
 * (This is an input file for POV-Ray, a free raytracer available
 * at http://www.povray.org/)
 */

global_settings {
	assumed_gamma 1.8
	ambient_light rgb<1, 1, 1>
}

#declare Mortar = texture {
	pigment { Gray80 }
}

// Texture by Chuck Fusner, http://www.enter.net/~cfusner
#declare RoughStone = texture { //rough stone texture...
	pigment { //nice and random on the pigment.
		granite
		color_map {
		[ 0 rgb .5 ]
		[ .25 rgb .65 ]
		[ .5 rgb .5 ]
		[ .75 rgb .7 ]
		[ 1 rgb .5 ]
		}
		frequency 100
	}
	normal { /*love that crackle! It's apparently quite
                 computation intensive, but with just the
                 right turbulence, it's got a range of apps.*/
		crackle 1
		warp {
		turbulence <.4,.4,.4> /*no more than <.5,.5,.5> for a rough
                                    stone effect. And less will
                                    look more "crystaline"*/
		lambda 2 //these you can tinker with
		octaves 6 //for a variety of effects
		omega .5 //though here they are at defaults.
		}
	}
	finish {
		specular .1 roughness 1
		diffuse .55

	}
}


union {
	// rows of rough cut stone
	#declare row = 0;
	#while ( row < 30 )
		#declare col = 0.5;
		#while ( col < 45 )
			box { <(-20 + col), row, -1>, <(-20 + col + 3.9), row + 1.9, 1>
				texture { RoughStone
					translate <col, col/2, 0>}
			}
			#declare col=col+4;
		#end
		#declare row=row+2;

		#declare col = 2.5;
		#while ( col < 45 )
			box { <(-20 + col), row, -1>, <(-20 + col + 3.9), row + 1.9, 1>
				texture { RoughStone
					translate <col, col/2, 0>}
			}
			#declare col=col+4;
		#end
		#declare row=row+2;
	#end

	// mortar
	box { <-20, 0, -0.9>, <30, 40, 0.9>
		texture { Mortar }
	}
}	


// illuminate the scene
light_source {
	<0,4.5,-20>
	color Gray40
}

light_source {
	<-20, 30, -20>
	color Gray70
}

light_source {
	<20, 30, -20>
	color Gray70
}

camera {
	location <2, 15, -28>
	look_at  <2, 15, 0>
}